Title                  :NTLAMDA
Keywords               :EELS
Computer               :DEC VAX 11/730-785, DEC PDP 11/2-11/73
Operating System       :VAXVMS, RT-11
Programming Language   :Fortran IV
Hardware Requirements  :None
Author(s)              :Nestor J. Zaluzec (312-972-5075,4964)
Correspondence Address :Argonne Nat. Lab, Electron Microscopy Center,Bldg 212
                       :Materials Science Division, Argonne, Illinois 60439,
Abstract:
 
NTLAMDA  is a simple fortran program which allows the user to calculate the
approximate thickness of a specimen based upon the measured EELS spectral
intensity ratio Io/It, which can be shown to be equal to the ratio of the
local thickness (t) to the mean free path for inelastic scattering (lamda).
The formulae are based upon the work of Egerton and Cheng (Ultramicroscopy, 21,
1987 pge 231-244), but has been generalized to simplify data input and entry.
The user must know the nominal elemental constitutents of the specimen, and is
prompted for all necessary input parameters required for the calculation.
Title                  :NTLAMDA
Keywords               :EELS
Computer               :DEC VAX 11/730-785, DEC PDP 11/2-11/73
Operating System       :VAXVMS, RT-11
Programming Language   :Fortran IV
Hardware Requirements  :None
Author(s)              :Nestor J. Zaluzec (312-972-5075,4964)
Correspondence Address :Argonne Nat. Lab, Electron Microscopy Center,Bldg 212
                       :Materials Science Division, Argonne, Illinois 60439,
References:
 
Egerton and Cheng (Ultramicroscopy, Vol. 21,1987 pge 231-244)

Compliation Procedure:

VAX VMS
	$FORTRAN NTLAMDA
	$LINK NTLAMDA
	$RUN NTLAMDA
RT-11
	.FORTRAN NTLAMDA
	.LINK NTLAMDA
	.RUN NTLAMDA

Test Data:



                 ************************************
                 *            NTLAMDA               *
                 * EELS T/L  Data Analysis Program  *
                 *          8712010001-NJZ          *
                 ************************************


Data Analysis on: 22-MAR-88 at 22:53:49

Enter Analysis/Specimen Identification :
EXAMPLE OF NTLAMDA FOR em  EMMPDL

Enter Accelerating Voltage (kV)? : 100

Enter Collection Semiangle (mR)? : 2.5

Enter  Experimental  T/L  Value? : 1.2

Number of Elements in Specimen?  : 1

Enter Element Symbol [AA] : AU


      Sym   Z   Atmwt    Wt%    At%   Wt%-Ratio  At%-Ratio
      =====================================================
      AU   79  196.97 100.00 100.00    1.0000    1.0000
      =====================================================

               Analysis Report T/Lamda Calculation
         ------------------------------------------------
          Accelerating Voltage     = 100.00 kV
          Collection Semiangle     =   2.50 mR
          Experimental Thick/Lamda =   1.20
          Calculated Lamda         =  85.00 nm
          Calculated Thickness     = 102.00 +/  20.40 nm
         ------------------------------------------------
         Note: Calculations Approximate Only for T/L < 1 


Do you wish to Enter more Data? [N]Y

Enter Accelerating Voltage (kV)? : 100

Enter Collection Semiangle (mR)? : 5.0

Enter  Experimental  T/L  Value? : 0.5

Number of Elements in Specimen?  : 2

Compositions in Wt% or At%? [At%] AT

Enter Element Symbol, Composition(At%) of Number  1 [AA,NN]
AL,50.

Enter Element Symbol, Composition(At%) of Number  2 [AA,NN]
NI,50.


      Sym   Z   Atmwt    Wt%    At%   Wt%-Ratio  At%-Ratio
      =====================================================
      AL   13   26.98  31.49  50.00    1.0000    1.0000
      NI   28   58.71  68.51  50.00    2.1759    1.0000
      =====================================================

               Analysis Report T/Lamda Calculation
         ------------------------------------------------
          Accelerating Voltage     = 100.00 kV
          Collection Semiangle     =   5.00 mR
          Experimental Thick/Lamda =   0.50
          Calculated Lamda         =  94.18 nm
          Calculated Thickness     =  47.09 +/   9.42 nm
         ------------------------------------------------
         Note: Calculations Approximate Only for T/L < 1 


Do you wish to Enter more Data? [N] Y

Enter Accelerating Voltage (kV)? : 300

Enter Collection Semiangle (mR)? : 3.

Enter  Experimental  T/L  Value? : 0.95

Number of Elements in Specimen?  : 1

Enter Element Symbol [AA] : AL


      Sym   Z   Atmwt    Wt%    At%   Wt%-Ratio  At%-Ratio
      =====================================================
      AL   13   26.98 100.00 100.00    1.0000    1.0000
      =====================================================

               Analysis Report T/Lamda Calculation
         ------------------------------------------------
          Accelerating Voltage     = 300.00 kV
          Collection Semiangle     =   3.00 mR
          Experimental Thick/Lamda =   0.95
          Calculated Lamda         = 187.82 nm
          Calculated Thickness     = 178.43 +/  35.69 nm
         ------------------------------------------------
         Note: Calculations Approximate Only for T/L < 1 



FORTRAN STOP

EMCMGR:
Title                  :NTLAMDA
Keywords               :EELS
Computer               :DEC VAX 11/730-785, DEC PDP 11/2-11/73
Operating System       :VAXVMS, RT-11
Programming Language   :Fortran IV
Hardware Requirements  :None
Author(s)              :Nestor J. Zaluzec (312-972-5075,4964)
Correspondence Address :Argonne Nat. Lab, Electron Microscopy Center,Bldg 212
                       :Materials Science Division, Argonne, Illinois 60439,



	PROGRAM NTLAMDA
C-------------------------------------------------------------------------
C
c	Program to calculate specimen thickness based upon
c	t/lamda measurements from EELS spectra
c	lamda is calculated by method described by Egerton & Cheng
c	Ultramicroscopy (21),1987 page 231-244
c
c	Version	Date	Initials	Reason
c-------------------------------------------------------------------------
c	1.0	12/1/87 NJZ		Creation
C
C-------------------------------------------------------------------------
C
C      STANDARD FORTRAN INTERACTIVE I/O DEVICES 
C      INPUT= #5 AND OUTPUT= #7
C      HARDCOPY OUTPUT DEVICE #8 (PRINTER)
C
C------------------------------------------------------------------------
C
c	COMMON /PARAM4/ PRGRM,ALINE(28),ELVL(28),RELINT(28)
C
C
C	COMMON ARRAYS NEEDED BY NEDQNT/NELQNT/NTLAMDA SEE DEFINITIONS BELOW
C
	COMMON ELM(20),ELN(20),EINT(20),EZ(20),EWT(20),ENE(20),
     CEDG(20),W(20),FA(20),U0(20),Q(20),C(20),CA(20),ALNID(6),AINT(20)
     C,SC(20),DEL(20),AC(20),ACP(20),SSC(20),SINV(20),WJ(20),FCORR(20)
     C,AVOG,YY,YN,CI,CW,RHOAV,XP,EO,CFLAG
C------------------------------------------------------------------------
C
C	DEFINITIONS OF BLANK COMMON
C
C-----------------------------------------------------------------------
C
C	ELM = ARRAY CONTAINING ELEMENT SYMBOL FOR ELEMENT I
C	ELN = ARRAY CONTAINING LINE SYMBOLS
C	EINT= ARRAY CONTAINING DETECTOR CORRECTED INTENSITY OR DETECTOR
C		EFFICIENCY * COMPOSITION DEPENDING UPON CLFAG
C	EZ  = ARRAY CONTAINING ATOMIC NUMBER
C	EWT = ARRAY CONTAINING ATOMIC WEIGHT
C	ENE = ARRAY CONTAINING X-RAY LINE ENERGY (KEV)
C	EDG = ARRAY CONTAINING X-RAY EDGE ENERGY (KEV)
C	W   = ARRAY CONTAINING FLUORESCENCE YIELD
C	FA  = ARRAY CONTAINING PARTITION FUNCTION
C	U0  = ARRAY CONTAINING OVERVOLTAGE
C	Q   = ARRAY CONTAINING CROSS-SECTION (BARNS)
C	C   = ARRAY CONTAINING CONCENTRATION (USUALLY WT%, BUT MAY REVERSE)
C	CA  = ARRAY CONTAINING CONCENTRATION (USUALLY AT%, BUT MAY REVERSE)
C	ALNID= ARRAY CONTAINING LINE DEFINITIONS KA,KB,K, LA,LB,L
C	AINT= ARRAY CONTAINING MEASURED INTENSITY, OR COMPOSITION DEPENDING ON
C		VALUE OF CFLAG
C	SC  = ARRAY CONTAINING NORMALIZED COMPOSITIONS
C	DEL = ARRAY CONTAINING ABSORPTION CORRECTION
C	AC  = ARRAY CONTAINING ABSORPTION COEFFICIENTS 
C	ACP = ARRAY CONTAINING ABSORPTION COEFFICIENTS
C	SSC = COMPOSITION NORMALIZING ARRAY
C	SINV=
C	WJ  = ARRAY NEEDED IN SEM/BULK ANALYSIS FOR NEDQNT.SEM
C	FCORR=ARRAY NEEDED IN SEM
C	AVOG= AVOGADRO'S NUMBER
C	YY,YN = YES, NO
C	CI  = INTENSITY FLAG
C	CW  = COMPOSITION FLAG
C	RHOAV= AVERAGE DENSITY
C	XP  = XP OF XPT ABSORPTION CORRECTION
C	EO  = ACCELERATING VOLTAGE KV
C	CFLAG= CALCULATION FLAG
C	     = 0 USER WANTS TO CALCULATE COMPOSITION FROM INTENSITY
C	     = 1 USER WANTS TO CALCULATE INTENSITY FROM COMPOSITION
C	WFLAG= COMPOSITION FLAG
C	     = 0 INPUT IN AT%
C	     = 1 INPUT IN WT%
C	DFLAG= DENSITY FLAG
C	     = 0 DENSITY UNKNOWN
C	     = 1 INPUT BY USER
C
C--------------------------------------------------------------------
C
C
C	DEFINE SYSTEM PARAMETERS
C
C      INPUT TITLES, # ELEMENTS, INCIDENT ENERGY
C
C	
2222	CALL TNTLAM		!WRITE PROGRAM TITLE
C
C
C
C	DEFINE SOME DEFAULT PARAMETERS
C
C
2223	WFLAG=0.
C
C
C
C	BEGIN DATA INPUT
C
C
C      INPUT INCIDENT ENERGY
C
C
 7    	WRITE(7,5)
 5   	FORMAT(/,$,' Enter Accelerating Voltage (kV)? : ')
	READ(5,4,ERR=7) EO
	IF((EO.LE.0.5).OR.(EO.GE.1201.)) GO TO 7
C
C	NOW THE SEMIANGLE
C
49	WRITE(7,50)
50	FORMAT(/,$,' Enter Collection Semiangle (mR)? : ')
	READ(5,4,ERR=49) BETA
	IF((BETA.LE.0.)) GO TO 49
c
c
c	INPUT T/L VALUE
C
C
622	WRITE(7,600)
600	FORMAT(/,$,' Enter  Experimental  T/L  Value? : ')
	READ (5,4,ERR=622) TLAMDA
	IF(TLAMDA.LE.0) GO TO 622
C
C
C
C      INPUT NUMBER OF MEASURED ELEMENTS
C
C
C
3000  WRITE(7,3)
 3    FORMAT(/,$,' Number of Elements in Specimen?  : ')
      READ(5,4,ERR=3000) AN
 4    FORMAT(1F10.0)
      N=AN
      IF (N.EQ.0) GO TO 3000
      IF (N.GT.20) WRITE (7,3001)
3001  FORMAT (' Maximum number of elements = 20 ! ')
      IF (N.GT.20) GO TO 3000
C
C	CHECK FOR TYPE OF COMPOSITION INPUT
C       CHECK FOR WT% OR AT% INPUT
C
C
C
	IF(N.EQ.1) GO TO 82
	WRITE(7,83)
83	FORMAT(/,$,' Compositions in Wt% or At%? [At%] ')
	READ(5,21) ANS
21	FORMAT (1A1)
	WFLAG=0.
	IF (ANS.EQ.CW) WFLAG=1.
 82   	CONTINUE
C
C      START INPUT LOOP 
C
	SUM =0.
	DO 8 I=1,N
11	IF (N.EQ.1) WRITE (7,103)
	IF (N.EQ.1) GO TO 104
	IF (WFLAG.EQ.0) WRITE(7,101) I
	IF (WFLAG.EQ.1) WRITE(7,102) I
101   	FORMAT(/,
     1' Enter Element Symbol, 
     1Composition(At%) of Number ',I2,' [AA,NN]')
102   	FORMAT(/,
     1' Enter Element Symbol,
     1Composition(Wt%) of Number ',I2,' [AA,NN]')
103	FORMAT(/,$,' Enter Element Symbol [AA] : ' )
104	IF (WFLAG.EQ.0) READ(5,10,ERR=11) ELM(I),CA(I)
	IF (WFLAG.EQ.1) READ(5,10,ERR=11) ELM(I),C(I)
 10	FORMAT(1A2,1X,1F10.0)
C
C      CALCULATE ATOMIC CONSTANTS OF THIS ELEMENT
C
C
C	GET THE atomic number
C
	EZ(I)=ATOMNR(ELM(I))
	IZ=EZ(I)
C
C	MORE PARAMETERS OF THE ELEMENT
C
	EWT(I)=ATOMWT(EZ(I))
C
C
C	CHECK FOR POSSIBLE INPUT ERROR
C
	IF((EZ(I).LE.0).OR.(EZ(I).GE.100)) GO TO 11
C
C      CALCULATE UNNORMALIZED COMPOSITION
C
	IF(N.EQ.1) CA(1)=100.
	IF(WFLAG.EQ.1) SUM=C(I) + SUM
	IF(WFLAG.EQ.0) SUM=CA(I) + SUM
 8	CONTINUE
	IF(N.EQ.1) CA(1)=100.
800	FORMAT(/,
     1' **************************************************',/,
     1' ERROR: Compositions donot add to 100%- NORMALIZING',/,
     1' **************************************************',/)
C
C      CONVERT WT% TO AT% AND NORMALIZE TO 100%
C
	IF(WFLAG.EQ.0) CALL ATTOWT(N)
	IF(WFLAG.EQ.0) CALL NRMW(N)
	IF(WFLAG.EQ.0) CALL NRMA(N)
	IF(WFLAG.EQ.1) CALL WTTOAT(N)
	IF(WFLAG.EQ.1) CALL NRMA(N)
	IF(WFLAG.EQ.1) CALL NRMW(N)
C
C	WRITE A COLUMN TITLE
C
	WRITE(7,142)
	WRITE(8,142)
 142  	FORMAT(//,1X,
     C6X,'Sym   Z   Atmwt',4X,'Wt%',4X,'At%   Wt%-Ratio  At%-Ratio')
	WRITE(7,598)
	WRITE(8,598)
598	FORMAT(' ',6X,
     C'=====================================================')
C
C	NOW OUTPUT Table of atomic parameters 
C
	DO 13 I=1,N
	IZ=EZ(I)
	WRITE(7,361) ELM(I),IZ,EWT(I),C(I),CA(I),C(I)/C(1),CA(I)/CA(1)
	WRITE(8,361) ELM(I),IZ,EWT(I),C(I),CA(I),C(I)/C(1),CA(I)/CA(1)
 361	FORMAT(1X,6X,1(1A2,1X),1X,I3,1X,1F7.2,1X
     C,2(F6.2,1X),2(1F9.4,1X))
13	CONTINUE
	WRITE(7,598)
	WRITE(8,598)
C
C	CALCULATE MEAN ATOMIC NUMBER
C
	ZBAR=0.
	ZEFF=0.
	DO 610 I=1,N
	ZBAR=ZBAR + CA(I)*EZ(I)**1.3/100.
	ZEFF=ZEFF + CA(I)*EZ(I)**0.3/100
610 	CONTINUE
	ZEFF=ZBAR/ZEFF
C
C	CALCULATE RELATIVISTIC FACTOR
C
	F= (1 + EO/1022.)/(1+EO/511)**2.
C
C
C	CALCULATE MEAN LOSS 
C
C
	EM=7.6*ZEFF**0.36
C
C
C	CALCULATE LAMDA
C
C
	CLAMDA= 106*F*EO/(EM*ALOG(2*BETA*EO/EM))
C
C	CALCULATE THICKNESS
C
	THICK=TLAMDA*CLAMDA
C
C
C	OUTPUT RESULTS
C
C
C
 	WRITE(7,146) EO,BETA,TLAMDA,CLAMDA,THICK,THICK*0.2
 	WRITE(8,146) EO,BETA,TLAMDA,CLAMDA,THICK,THICK*0.2
 146  	FORMAT(/,
     C10X,'      Analysis Report T/Lamda Calculation',/,
     C10X,'------------------------------------------------',/,
     C10X,' Accelerating Voltage     = ',1F6.2,' kV',/,
     C10X,' Collection Semiangle     = ',1F6.2,' mR',/,
     C10X,' Experimental Thick/Lamda = ',1F6.2,/,
     C10X,' Calculated Lamda         = ',1F6.2,' nm',/,
     C10X,' Calculated Thickness     = ',1F6.2,' +/ ',1f6.2,' nm',/,
     C10X,'------------------------------------------------',/,
     C10x,'Note: Calculations Approximate Only for T/L < 1 ',//)
C
C
C
	WRITE (7,9992)
 9992	FORMAT($,' Do you wish to Enter more Data? [N]')
	READ (5,21) ANS
	IF(ANS.EQ.'Y') GO TO 2223
C
C	THAT'S ALL FOLKS
C
	STOP
	END

C
C
C
C------------------------------------------------------------------
C
C		SUBROUTINES AND FUNCTIONS REQUIRED BY NEDQNT
C
C------------------------------------------------------------------
C
C
      FUNCTION ATOMNR(SYMBOL)
C
C OUTPUTS ATOMIC NUMBER OF ELEMENT WHICH CORRESPONDS TO SYMBOL
C
      DIMENSION SS(18),NUM(18)
      COMMON /ELEMNT/ CS(100),ALNID(6)
      DATA CS/' H','HE','LI','BE',' B',' C',' N',' O',' F','NE'
     1,'NA','MG','AL','SI',' P',' S','CL','AR',' K','CA','SC','TI',
     2' V','CR','MN','FE','CO','NI','CU','ZN','GA','GE','AS','SE',
     3'BR','KR','RB','SR',' Y','ZR','NB','MO','TC','RU','RH','PD',
     4'AG','CD','IN','SN','SB','TE',' I','XE','CS','BA','LA','CE',
     5'PR','ND','PM','SM','EU','GD','TB','DY','HO','ER','TM','YB',
     6'LU','HF','TA',' W','RE','OS','IR','PT','AU','HG','TL','PB',
     7'BI','PO','AT','RN','FR','RA','AC','TH','PA',' U','NP','PU',
     8'AM','CM','BK','CF','ES','FM'/
      DATA ALNID/'KA','LA','MA','KB','LB','MB'/
      DATA SS/'NO','H ','B ','C ','N ','O ',
     9'F ','P ','S ','A ','K ','V ','Y ','I ','W ','U ',' A','CB' /
     9,NUM/1000,1,5,6,7,8,9,15,16,18,19,23,39,53,74,92,18,41/
      DO 1 I=1,100
      IF(SYMBOL-CS(I))1,5,1
 1    CONTINUE
      DO 2 I=1,18
      IF (SYMBOL-SS(I))2,4,2
 2    CONTINUE
        WRITE(7,3) SYMBOL
 3     FORMAT (' THE ELEMENT ',A2,' DOES NOT EXIST')
      GO TO 7
 4    SYMBOL=CS(NUM(I))
      I=NUM(I)
 5    ATOMNR=I
      GO TO 6
 7    ATOMNR=0
 6    RETURN
      END
C
C
C
C
C
      FUNCTION ATOMWT(Z)
C
C OUTPUTS ATOMIC WEIGHT OF ELEMENT Z
C
C
      DIMENSION A(100)
      DATA A/1.008,4.003,6.939,9.012,10.811,12.011,14.007,15.999,18.998,
     120.183,22.990,24.312,26.982,28.086,30.974,32.064,35.453,39.948,
     239.102,40.080,44.956,47.900,50.942,51.996,54.938,55.847,58.933,
     358.710,63.540,65.370,69.720,72.590,74.922,78.960,79.909,83.800,
     485.470,87.620,88.905,91.220,92.906,95.940,99.000,101.070,102.905,
     5106.400,107.870,112.400,114.820,118.690,121.750,127.600,126.904,
     6131.300,132.905,137.340,138.910,140.120,140.907,144.240,147.000,
     7150.350,151.960,157.250,158.924,162.500,164.930,167.260,168.934,
     8173.040,174.970,178.490,180.948,183.850,186.200,190.200,192.200,
     9195.090,196.967,200.590,204.370,207.190,208.980,210.000,210.000,
     1222.000,223.000,226.000,227.000,232.038,231.000,238.030,237.000,
     2244.000,243.000,247.000,247.000,251.000,254.000,253.000/
      I=Z
      ATOMWT=A(I)
      RETURN
      END
C
C
C
C
C
      SUBROUTINE ATTOWT(N)
C
C
C      THIS SUBROUTINE CONVERTS AT% INTO WT% 
C      FOR N ELEMENTS
C
C
      COMMON ELM(20),ELN(20),EINT(20),EZ(20),EWT(20),ENE(20),
     CEDG(20),W(20),FA(20),U0(20),Q(20),C(20),CA(20),ALNID(6),AINT(20)
     C,SC(20),DEL(20),AC(20),ACP(20),FZ(20),SINV(20),WJ(20),FCORR(20)
     C,AVOG,YY,YN,CI,CW,RHOAV,XP
      SUM=0.
      DO 1 I=1,N
      C(I)=CA(I)*EWT(I)
 1    SUM=SUM+C(I)
      DO 2 I=1,N
 2    C(I)=C(I)/SUM
      RETURN
      END
C
C
C
      FUNCTION DEN(Z)
C
C	OUTPUTS DENSITY OF PURE ELEMENT
C
      DIMENSION AD(100)
      DATA AD /.071,.126,.53,1.85,2.34,2.26,.81,1.14,1.505,1.2
     1,.97,1.74,2.70,2.33,1.82,2.07,1.56,1.40,.86,1.55
     2,3.,4.51,6.1,7.19,7.43,7.86,8.9,8.9,8.96,7.14
     3,5.91,5.32,5.72,4.79,3.12,2.6,1.53,2.6,4.47,6.49
     4,8.41,10.2,11.5,12.2,12.4,12.,10.5,8.65,7.31,7.3
     5,6.62,6.24,4.94,3.06,1.9,3.5,6.17,6.67,6.77,7.
     6,999.,7.54,5.26,7.89,8.27,8.54,8.8,9.05,9.33,6.98
     7,9.84,13.1,16.6,19.3,21.,22.6,22.5,21.4,19.3,13.6
     8,11.85,11.4,9.8,9.2,999.,999.,999.,5.,999.,11.7
     9,15.4,19.07,19.5,999.,11.7,999.,999.,999.,999.,999./
      I=Z
      DEN=AD(I)
      RETURN
      END
C
C
C
C
	SUBROUTINE TNTLAM
C
C
C	SUBROUTINE TO WRITE TITLES & START UP NEDQNT PROGRAM
C
C
	DIMENSION INAME(36)
	BYTE DAY(9),TIM(8)
	COMMON ELM(20),ELN(20),EINT(20),EZ(20),EWT(20),ENE(20),
     CEDG(20),W(20),FA(20),U0(20),Q(20),C(20),CA(20),ALNID(6),AINT(20)
     C,SC(20),DEL(20),AC(20),ACP(20),SSC(20),SINV(20),WJ(20),FCORR(20)
     C,AVOG,YY,YN,CI,CW,RHOAV,XP,EO,CFLAG
C
C
C	DEFINE SYSTEM PARAMETERS
C
C
C	CONSTANTS
C
C
      DATA AVOG/6.023E23/
      DATA YY,YN,CI,CW/'Y','N','I','W'/
      DATA ALNID/'KA','KB','K ','LA','LB','L '/
C
C
C
	WRITE (7,1)
1	FORMAT(//////,
     C18X,'************************************',/,
     C18X,'*            NTLAMDA               *',/,
     C18X,'* EELS T/L  Data Analysis Program  *',/,
     C18X,'*          8712010001-NJZ          *',/,
     C18X,'************************************',//)
C
C
C
C	DEFINE AN OUTPUT FILE FOR RESULTS OR
C	GIVE OPERATOR OPTION FOR OUTPUT NL:,TT:,LP:,DEV:NAME.EXT
C
C
c	WRITE(7,2)
C2	FORMAT(//,' Enter Hardcopy Output Device 
C     C(NL:,LP:,DEV:NAME.EXT):',/)
C
C	THIS VERSION ASSIGNS AN OUTPUT FILE BELOW
C	IF YOU WISH TO DEFINE THE OUTPUT DEVICE CHANGE THE NEXT
C	LINE AND REMOVE THE COMMENT STATEMENTS BEFORE THE PRECEEDING
C	WRITE STATEMENTS
C
C
	CALL ASSIGN(8,'LP:',3)
C
C	LETS TELL THE USER THE DATE AND TIME
C
	WRITE(8,1)
998	CALL DATE (DAY)
	CALL TIME (TIM)
	WRITE(7,10) DAY,TIM
	WRITE(8,10) DAY,TIM
10	FORMAT(' Data Analysis on: ',9A1,' at ',8A1,/)
C
C
C
C	READ & WRITE ID
C
      WRITE(7,30)
 30   FORMAT(' Enter Analysis/Specimen Identification :')
      READ(5,31) INAME
 31   FORMAT(36A2)
      WRITE(8,32) INAME
 32  	FORMAT(' Identification  : ',36A2,/)
	RETURN
	END
C
C
C
C
      SUBROUTINE WTTOAT(N)
C
C
C      THIS SUBROUTINE CONVERTS WT% TO AT% 
C
C
      COMMON ELM(20),ELN(20),EINT(20),EZ(20),EWT(20),ENE(20),
     CEDG(20),W(20),FA(20),U0(20),Q(20),C(20),CA(20),ALNID(6),AINT(20)
     C,SC(20),DEL(20),AC(20),ACP(20),FZ(20),SINV(20),WJ(20),FCORR(20)
     C,AVOG,YY,YN,CI,CW,RHOAV,XP
      SUM=0.
      DO 1 I=1,N
      CA(I)=C(I)/EWT(I)
 1    SUM=SUM+CA(I)
      DO 2 I=1,N
 2    CA(I)=CA(I)/SUM
      RETURN
      END
C
C
C
C
      SUBROUTINE NRMW(N)
C
C
C      SUBROUTINE TO NORMALIZE WT% COMPOSITIONS TO 100% FOR
C      N ELEMENTS 
C
      COMMON ELM(20),ELN(20),EINT(20),EZ(20),EWT(20),ENE(20),
     CEDG(20),W(20),FA(20),U0(20),Q(20),C(20),CA(20),ALNID(6),AINT(20)
     C,SC(20),DEL(20),AC(20),ACP(20),FZ(20),SINV(20),WJ(20),FCORR(20)
     C,AVOG,YY,YN,CI,CW,RHOAV,XP
      SUM=0.
      DO 1 I=1,N
  1   SUM=SUM+C(I)
      DO 2 I=1,N
 2    C(I)=100.*C(I)/SUM
      RETURN
      END
C
C
C
C
      SUBROUTINE NRMA(N)
C
C
C      SUBROUTINE TO NORMALIZE AT% COMPOSITIONS TO 100% FOR
C      N ELEMENTS 
C
      COMMON ELM(20),ELN(20),EINT(20),EZ(20),EWT(20),ENE(20),
     CEDG(20),W(20),FA(20),U0(20),Q(20),C(20),CA(20),ALNID(6),AINT(20)
     C,SC(20),DEL(20),AC(20),ACP(20),FZ(20),SINV(20),WJ(20),FCORR(20)
     C,AVOG,YY,YN,CI,CW,RHOAV,XP
      SUM=0.
      DO 1 I=1,N
  1   SUM=SUM+CA(I)
      DO 2 I=1,N
 2    CA(I)=100.* CA(I)/SUM
      RETURN
      END